dnl Process this file with autoconf to produce a configure script.
AC_REVISION([$Id$])dnl

AC_INIT(spf.c)
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE(zms_spf, 0.04)
AM_CONFIG_HEADER(config.h)
AM_C_PROTOTYPES
AC_LANG_C
AC_PROG_CC

AC_PROG_MAKE_SET
AC_SUBST(PROGS)dnl
AC_SUBST(LIBPROGS)dnl
AC_PATH_PROG(ECHO, echo, echo)dnl
AC_PATH_PROG(SED, sed, sed)dnl
AC_PROG_INSTALL
AM_PROG_LIBTOOL

AC_PATH_PROG(ZMSCANNER_CONFIG,zmscanner-config)
AC_ARG_WITH(zmscanner_config, [  --with-zmscanner-config=PATH path to zmscanner-config program],
	[ZMSCANNER_CONFIG=$withval])
ZMSCANNER_VERSION=`$ZMSCANNER_CONFIG --version`
if test $? != 0; then
	AC_MSG_ERROR([cannot run zmscanner-config program])
fi
case "$ZMSCANNER_VERSION" in
1.9[[5-9]]) ;;
0.*|1.*)
	AC_MSG_ERROR([incompatible version $ZMSCANNER_VERSION of zmscanner]);;
esac
AC_MSG_RESULT([using ZMScanner version $ZMSCANNER_VERSION])
AC_SUBST(ZMSCANNER_VERSION)
CPPFLAGS="`$ZMSCANNER_CONFIG --cflags` $CPPFLAGS"
LIBS="`$ZMSCANNER_CONFIG --libs` $LIBS"
zmslibdir="`$ZMSCANNER_CONFIG --libexecdir`"
ZMSCANNER_COMMAND="`$ZMSCANNER_CONFIG --binpath`"
ZMSCHAT_COMMAND="`$ZMSCANNER_CONFIG --chatpath`"

AC_ARG_WITH(libspf_prefix, [  --with-libspf-prefix=PATH prefix where libspf or libspf2 is installed],
	[libspf_prefix=$withval])
if test X$libspf_prefix != X; then
	CPPFLAGS="$CPPFLAGS -I$libspf_prefix/include"
	LIBS="$LIBS -L$libspf_prefix/lib"
fi

dnl G_RESULT([libspf_prefix = $libspf_prefix])
dnl AC_MSG_RESULT([CPPFLAGS = $CPPFLAGS])
dnl AC_MSG_RESULT([LIBS = $LIBS])

AC_SUBST(LIBS)
AC_SUBST(CPPFLAGS)
AC_SUBST(zmslibdir)
AC_SUBST(ZMSCANNER_COMMAND)
AC_SUBST(ZMSCHAT_COMMAND)

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(errno.h unistd.h stddef.h fcntl.h sys/stat.h)
AC_CHECK_HEADERS(sys/utsname.h)
AC_CHECK_HEADERS(sys/socket.h netinet/in.h arpa/inet.h)
AC_CHECK_HEADERS(zmscanner.h)
libspf=yes
libspf2=yes
AC_CHECK_HEADERS(spf.h,,[libspf=no])
AC_CHECK_HEADERS(spf2/spf.h,,[libspf2=no],
[
#ifdef HAVE_SYS_TYPES_H
#include <sys/types.h>
#endif
#ifdef HAVE_SYS_SOCKET_H
# include <sys/socket.h>
#endif
#ifdef HAVE_NETINET_IN_H
# include <netinet/in.h>
#endif
#ifdef HAVE_ARPA_INET_H
# include <arpa/inet.h>
#endif
])

dnl Checks for library functions.
AC_CHECK_FUNCS(syslog uname gethostname)
AC_CHECK_LIB(spf,SPF_init,,[libspf=no])
AC_CHECK_LIB(spf2,SPF_get_lib_version,,[libspf2=no])

if test X$libspf = Xno && test X$libspf2 = Xno; then
  AC_MSG_ERROR([neither libspf nor libspf2 present, try --with-libspf-prefix])
fi
if test X$libspf = Xyes; then
	AC_DEFINE(USE_LIBSPF,1,[Can use original libspf API])
	IFACE_OBJS="libspf_iface.lo"
fi
if test X$libspf2 = Xyes; then
	AC_DEFINE(USE_LIBSPF2,1,[Can use libspf2 API])
	IFACE_OBJS="libspf2_iface.lo"
fi
AC_SUBST(IFACE_OBJS)
AC_MSG_RESULT([libspf:  $libspf])
AC_MSG_RESULT([libspf2: $libspf2])

AC_CONFIG_FILES([Makefile test.conf startserver tryscan stopserver],
	[test -f startserver && chmod +x startserver
	 test -f tryscan && chmod +x tryscan
	 test -f stopserver && chmod +x stopserver])
AC_OUTPUT