remove deprecated expandSrv
[pdns-pipe-nmc.git] / NmcTransform.hs
1 module NmcTransform ( seedNmcDom
2                     , descendNmcDom
3                     ) where
4
5 import Prelude hiding (lookup)
6 import Data.ByteString.Lazy (ByteString)
7 import Data.Text.Lazy (splitOn, pack, unpack)
8 import Data.Map.Lazy (empty, lookup, delete, size, singleton
9                      , foldrWithKey, insert, insertWith)
10 import Control.Monad (foldM)
11 import Data.Aeson (decode)
12 import Data.Default.Class (def)
13
14 import NmcDom
15
16 -- | Perform query and return error string or parsed domain object
17 queryNmcDom ::
18   (String -> IO (Either String ByteString)) -- ^ query operation action
19   -> String                                 -- ^ key
20   -> IO (Either String NmcDom)              -- ^ error string or domain
21 queryNmcDom queryOp key = do
22   l <- queryOp key
23   case l of
24     Left estr -> return $ Left estr
25     Right str -> case decode str :: Maybe NmcDom of
26       Nothing  -> return $ Left $ "Unparseable value: " ++ (show str)
27       Just dom -> return $ Right dom
28
29 -- | Try to fetch "delegate" or "import" object and merge them into the
30 --   base domain. Original "import" element is removed, but newly
31 --   merged data may contain new "import" or "delegate", so the objects
32 --   that are about to be merged are processed recursively until there
33 --   are no more "import" and "deletage" attributes (or the depth gauge
34 --   reaches zero).
35 mergeIncl ::
36   (String -> IO (Either String ByteString)) -- ^ query operation action
37   -> Int                                    -- ^ recursion counter
38   -> NmcDom                                 -- ^ base domain
39   -> IO (Either String NmcDom)              -- ^ result with merged import
40 mergeIncl queryOp depth base = do
41   let
42     mbase = (splitSubdoms . mergeSelf) base
43     base' = mbase {domDelegate = Nothing, domImport = Nothing}
44   -- print base
45   if depth <= 0 then return $ Left "Nesting of imports is too deep"
46     else case ((domDelegate mbase), (domImport mbase)) of
47       (Nothing,  Nothing  ) -> return $ Right base'
48       (Nothing,  Just keys) -> foldM mergeIncl1 (Right base') keys
49       (Just key, _        ) -> mergeIncl1 (Right def) key
50   where
51     mergeIncl1 (Left  err) _   = return $ Left err -- can never happen
52     mergeIncl1 (Right acc) key = do
53       sub <- queryNmcDom queryOp key
54       case sub of
55         Left  err  -> return $ Left err
56         Right sub' -> mergeIncl queryOp (depth - 1) $ sub' `merge` acc
57
58 -- | If there is an element in the map with key "", merge the contents
59 --   and remove this element. Do this recursively.
60 mergeSelf :: NmcDom -> NmcDom
61 mergeSelf base =
62   let
63     map   = domSubmap base
64     base' = base {domSubmap = removeSelf map}
65     removeSelf Nothing    = Nothing
66     removeSelf (Just map) = if size map' == 0 then Nothing else Just map'
67       where map' = delete "" map
68   in
69     case map of
70       Nothing   -> base'
71       Just map' ->
72         case lookup "" map' of
73           Nothing  -> base'
74           Just sub -> (mergeSelf sub) `merge` base'
75         -- recursion depth limited by the size of the record
76
77 -- | Convert map elements of the form "subN...sub2.sub1.dom.bit"
78 --   into nested map and merge it
79 splitSubdoms :: NmcDom -> NmcDom
80 splitSubdoms base =
81   let
82     base' = base { domSubmap = Nothing }
83   in
84     case domSubmap base of
85       Nothing -> base'
86       Just sdmap -> (def { domSubmap = Just sdmap' }) `merge` base'
87         where
88           sdmap' = foldrWithKey stow empty sdmap
89           stow fqdn sdom acc = insertWith merge fqdn' sdom' acc
90             where
91               (fqdn', sdom') =
92                 nest (filter (/= "") (splitOnDots fqdn), sdom)
93               splitOnDots s = map unpack (splitOn (pack ".") (pack s))
94               nest ([], v)   = (fqdn, v) -- can split result be empty?
95               nest ([k], v)  = (k, v)
96               nest (k:ks, v) =
97                 nest (ks, def { domSubmap = Just (singleton k v) })
98
99 -- | transfer some elements of `base` into `sub`, notably TLSA
100 propagate :: NmcDom -> NmcDom -> NmcDom
101 propagate base sub = sub -- FIXME implement it
102  
103 -- | Presence of some elements require removal of some others
104 normalizeDom :: NmcDom -> NmcDom
105 normalizeDom dom = foldr id dom [ translateNormalizer
106                                 , nsNormalizer
107                                 ]
108   where
109     nsNormalizer dom = case domNs dom of
110       Nothing  -> dom
111       Just ns  -> def { domNs = domNs dom, domEmail = domEmail dom }
112     translateNormalizer dom = case domTranslate dom of
113       Nothing  -> dom
114       Just tr  -> dom { domSubmap = Nothing }
115
116 -- | Merge imports and Selfs and follow the maps tree to get dom
117 descendNmcDom ::
118   (String -> IO (Either String ByteString)) -- ^ query operation action
119   -> [String]                               -- ^ subdomain chain
120   -> NmcDom                                 -- ^ base domain
121   -> IO (Either String NmcDom)              -- ^ fully processed result
122 descendNmcDom queryOp subdom base = do
123   base' <- mergeIncl queryOp 10 base
124   case subdom of
125     []   -> return $ fmap normalizeDom base'
126     d:ds ->
127       case base' of
128         Left err     -> return base'
129         Right base'' ->
130           case domSubmap base'' of
131             Nothing  -> return $ Right def
132             Just map ->
133               case lookup d map of
134                 Nothing  -> return $ Right def
135                 Just sub -> descendNmcDom queryOp ds $ propagate base'' sub
136
137 -- | Initial NmcDom populated with "import" only, suitable for "descend"
138 seedNmcDom ::
139   String        -- ^ domain key (without namespace prefix)
140   -> NmcDom     -- ^ resulting seed domain
141 seedNmcDom dn = def { domImport = Just (["d/" ++ dn])}