NmcDom.hs

   1 {-# LANGUAGE OverloadedStrings #-}
   2
   3 module NmcDom   ( NmcDom(..)
   4                 , NmcRRSrv(..)
   5                 , NmcRRI2p(..)
   6                 , NmcRRTlsa(..)
   7                 , NmcRRDs(..)
   8                 , merge
   9                 ) where
  10
  11 import Prelude hiding (length)
  12 import Control.Applicative ((<$>), (<*>), liftA2, empty, pure)
  13 import Data.Char
  14 import Data.Text (Text, unpack)
  15 import Data.List (union)
  16 import Data.List.Split
  17 import Data.Vector ((!), length)
  18 import qualified Data.Vector as V (singleton)
  19 import Data.Map (Map, unionWith, foldrWithKey)
  20 import qualified Data.Map as M (singleton, empty, insert, insertWith)
  21 import qualified Data.HashMap.Strict as H (lookup, foldrWithKey)
  22 import Data.Aeson
  23 import Data.Aeson.Types
  24 import Data.Default.Class
  25
  26 -- Variant of Aeson's `.:?` that interprets a String as a
  27 -- single-element list, so it is possible to have either
  28 --      "ip":["1.2.3.4"]
  29 -- or
  30 --      "ip":"1.2.3.4"
  31 -- with the same result.
  32 (.:/) :: (FromJSON a) => Object -> Text -> Parser (Maybe a)
  33 obj .:/ key = case H.lookup key obj of
  34                Nothing -> pure Nothing
  35                Just v  -> case v of
  36                         String s -> parseJSON $ Array (V.singleton v)
  37                         _        -> parseJSON v
  38
  39 data IntRRService = IntRRService { isvName       :: String
  40                                  , isvProto      :: String
  41                                  , isvPrio       :: Int
  42                                  , isvWeight     :: Int
  43                                  , isvPort       :: Int
  44                                  , isvHost       :: String
  45                                  } deriving (Show, Eq)
  46
  47 instance FromJSON IntRRService where
  48         parseJSON (Array a) =
  49                 if length a == 6 then IntRRService
  50                         <$> parseJSON (a ! 0)
  51                         <*> parseJSON (a ! 1)
  52                         <*> parseJSON (a ! 2)
  53                         <*> parseJSON (a ! 3)
  54                         <*> parseJSON (a ! 4)
  55                         <*> parseJSON (a ! 5)
  56                 else empty
  57         parseJSON _ = empty
  58
  59 makeMx :: Object -> Parser (Maybe [String])
  60 makeMx o =
  61   case H.lookup "service" o of
  62     Nothing          -> pure Nothing
  63     Just (Array a) -> do
  64       isvl <- parseJSON (Array a)
  65       return $ Just $ map mxStr $ filter mxMatch isvl
  66         where
  67           mxMatch isv = isvName isv  == "smtp"
  68                      && isvProto isv == "tcp"
  69                      && isvPort isv  == 25
  70           mxStr isv = (show (isvPrio isv)) ++ "\t" ++ (isvHost isv)
  71     Just _ -> empty
  72
  73 makeSubmap :: Object -> Parser (Maybe (Map String NmcDom))
  74 makeSubmap o = takeTls o `fmerge` takeSrv o `fmerge` takeMap o
  75   where fmerge = liftA2 merge
  76
  77 takeMap :: Object -> Parser (Maybe (Map String NmcDom))
  78 takeMap o =
  79   case H.lookup "map" o of
  80     Nothing          -> pure Nothing
  81     Just (Object mo) -> H.foldrWithKey addmapentry (pure (Just M.empty)) mo
  82       where
  83         addmapentry "" v acc = parseJSON v >>= inject acc ""
  84         addmapentry k  v acc = nest (splitOn "." (unpack k)) v acc
  85         nest []     v acc = empty -- does not happen as a result of splitOn
  86         nest [""]   v acc = empty -- empty element of fqdn forbidden
  87         nest [d]    v acc = parseJSON v >>= inject acc d
  88         nest (d:ds) v acc =
  89           nest ds v acc >>= (inject acc d) . (\r -> def { domSubmap = r })
  90         inject acc d r = (fmap.fmap) (M.insertWith merge d r) acc
  91     _ -> empty
  92
  93 takeSrv :: Object -> Parser (Maybe (Map String NmcDom))
  94 takeSrv o =
  95   case H.lookup "service" o of
  96     Nothing          -> pure Nothing
  97     Just (Array a) -> do
  98       isvl <- parseJSON (Array a)
  99       return $ foldr addSrv (Just M.empty) isvl
 100         where
 101           addSrv isv acc = subm `merge` acc
 102             where
 103               subm = Just (M.singleton ("_" ++ isvProto isv) sub2)
 104               sub2 = def { domSubmap =
 105                              Just (M.singleton ("_" ++ isvName isv) sub3) }
 106               sub3 = def { domSrv = Just [ NmcRRSrv (isvPrio isv)
 107                                                     (isvWeight isv)
 108                                                     (isvPort isv)
 109                                                     (isvHost isv) ] }
 110     Just _ -> empty
 111
 112 -- takeTls is almost, but not quite, entirely unlike takeSrv
 113 takeTls :: Object -> Parser (Maybe (Map String NmcDom))
 114 takeTls o =
 115   case H.lookup "tls" o of
 116     Nothing         -> pure Nothing
 117     Just (Object t) ->
 118       (parseJSON (Object t) :: Parser (Map String (Map String [NmcRRTlsa])))
 119         >>= tmap2dmap
 120           where
 121             tmap2dmap :: Map String (Map String [NmcRRTlsa])
 122                       -> Parser (Maybe (Map String NmcDom))
 123                 -- FIXME return parse error on invalid proto or port
 124             tmap2dmap m1 = return $ foldrWithKey addprotoelem (Just M.empty) m1
 125             addprotoelem k1 m2 acc = protoelem k1 m2 `merge` acc
 126             protoelem k1 m2 = Just (M.singleton ("_" ++ k1) (pmap2dmap m2))
 127             pmap2dmap m2 = foldrWithKey addportelem def m2
 128             addportelem k2 v acc = portelem k2 v `merge` acc
 129             portelem k2 v =
 130               def { domSubmap = Just (M.singleton ("_" ++ k2)
 131                                       def { domTlsa = Just v }) }
 132     Just _ -> empty
 133
 134 class Mergeable a where
 135         merge :: a -> a -> a -- bias towads second arg
 136
 137 instance (Ord k, Mergeable a) => Mergeable (Map k a) where
 138         merge mx my = unionWith merge my mx
 139
 140 -- Alas, the following is not possible in Haskell :-(
 141 -- instance Mergeable String where
 142 --         merge _ b = b
 143
 144 instance Mergeable Value where
 145         merge _ b = b
 146
 147 instance Mergeable a => Mergeable (Maybe a) where
 148         merge (Just x) (Just y) = Just (merge x y)
 149         merge Nothing  (Just y) = Just y
 150         merge (Just x) Nothing  = Just x
 151         merge Nothing  Nothing  = Nothing
 152
 153 instance Eq a => Mergeable [a] where
 154         merge xs ys = union xs ys
 155
 156 data NmcRRSrv = NmcRRSrv
 157                         { srvPrio       :: Int
 158                         , srvWeight     :: Int
 159                         , srvPort       :: Int
 160                         , srvHost       :: String
 161                         } deriving (Show, Eq)
 162
 163 instance Mergeable NmcRRSrv where
 164         merge _ b = b
 165
 166 data NmcRRI2p = NmcRRI2p
 167                         { i2pDestination :: Maybe String
 168                         , i2pName        :: Maybe String
 169                         , i2pB32         :: Maybe String
 170                         } deriving (Show, Eq)
 171
 172 instance FromJSON NmcRRI2p where
 173         parseJSON (Object o) = NmcRRI2p
 174                 <$> o .:? "destination"
 175                 <*> o .:? "name"
 176                 <*> o .:? "b32"
 177         parseJSON _ = empty
 178
 179 instance Mergeable NmcRRI2p where
 180         merge _ b = b
 181
 182 data NmcRRTlsa = NmcRRTlsa
 183                         { tlsMatchType  :: Int -- 0:exact 1:sha256 2:sha512
 184                         , tlsMatchValue :: String
 185                         , tlsIncSubdoms :: Int -- 1:enforce on subdoms 0:no
 186                         } deriving (Show, Eq)
 187
 188 instance FromJSON NmcRRTlsa where
 189         parseJSON (Array a) =
 190                 if length a == 3 then NmcRRTlsa
 191                         <$> parseJSON (a ! 0)
 192                         <*> parseJSON (a ! 1)
 193                         <*> parseJSON (a ! 2)
 194                 else empty
 195         parseJSON _ = empty
 196
 197 instance Mergeable NmcRRTlsa where
 198         merge _ b = b
 199
 200 data NmcRRDs = NmcRRDs
 201                         { dsKeyTag      :: Int
 202                         , dsAlgo        :: Int
 203                         , dsHashType    :: Int
 204                         , dsHashValue   :: String
 205                         } deriving (Show, Eq)
 206
 207 instance FromJSON NmcRRDs where
 208         parseJSON (Array a) =
 209                 if length a == 4 then NmcRRDs
 210                         <$> parseJSON (a ! 0)
 211                         <*> parseJSON (a ! 1)
 212                         <*> parseJSON (a ! 2)
 213                         <*> parseJSON (a ! 3)
 214                 else empty
 215         parseJSON _ = empty
 216
 217 instance Mergeable NmcRRDs where
 218         merge _ b = b
 219
 220 data NmcDom = NmcDom    { domIp          :: Maybe [String]
 221                         , domIp6         :: Maybe [String]
 222                         , domTor         :: Maybe String
 223                         , domI2p         :: Maybe NmcRRI2p
 224                         , domFreenet     :: Maybe String
 225                         , domAlias       :: Maybe String
 226                         , domTranslate   :: Maybe String
 227                         , domEmail       :: Maybe String
 228                         , domLoc         :: Maybe String
 229                         , domInfo        :: Maybe Value
 230                         , domNs          :: Maybe [String]
 231                         , domDelegate    :: Maybe String
 232                         , domImport      :: Maybe [String]
 233                         , domSubmap      :: Maybe (Map String NmcDom)
 234                         , domFingerprint :: Maybe [String]
 235                         , domDs          :: Maybe [NmcRRDs]
 236                         , domMx          :: Maybe [String]    -- Synthetic
 237                         , domSrv         :: Maybe [NmcRRSrv]  -- Synthetic
 238                         , domTlsa        :: Maybe [NmcRRTlsa] -- Synthetic
 239                         } deriving (Show, Eq)
 240
 241 instance Default NmcDom where
 242   def = NmcDom Nothing Nothing Nothing Nothing Nothing Nothing Nothing
 243                Nothing Nothing Nothing Nothing Nothing Nothing Nothing
 244                Nothing Nothing Nothing Nothing Nothing
 245
 246 instance FromJSON NmcDom where
 247         -- Wherever we expect a domain object, there may be a string
 248         -- containing IPv4 address. Interpret it as such.
 249         -- Question: shall we try to recognize IPv6 addresses too?
 250         parseJSON (String s) =
 251                  return $ if isIPv4 s'
 252                             then def { domIp = Just [s'] }
 253                             else def
 254                           where
 255                             s' = unpack s
 256                             isIPv4 x = all isNibble $ splitOn "." x
 257                             isNibble x =
 258                               if all isDigit x then (read x :: Int) < 256
 259                               else False
 260         parseJSON (Object o) = NmcDom
 261                 <$> o .:/ "ip"
 262                 <*> o .:/ "ip6"
 263                 <*> o .:? "tor"
 264                 <*> o .:? "i2p"
 265                 <*> o .:? "freenet"
 266                 <*> o .:? "alias"
 267                 <*> o .:? "translate"
 268                 <*> o .:? "email"
 269                 <*> o .:? "loc"
 270                 <*> o .:? "info"
 271                 <*> o .:/ "ns"
 272                 <*> o .:? "delegate"
 273                 <*> o .:/ "import"
 274                 <*> makeSubmap o
 275                 <*> o .:/ "fingerprint"
 276                 <*> o .:? "ds"
 277                 <*> makeMx o
 278                 <*> return Nothing -- domSrv created in subdomains
 279                 <*> return Nothing -- domTlsa created in subdomains
 280         parseJSON _ = empty
 281
 282 instance Mergeable NmcDom where
 283         merge sub dom = dom     { domIp =          mergelm domIp
 284                                 , domIp6 =         mergelm domIp6
 285                                 , domTor =         choose  domTor
 286                                 , domI2p =         mergelm domI2p
 287                                 , domFreenet =     choose  domFreenet
 288                                 , domAlias =       choose  domAlias
 289                                 , domTranslate =   choose  domTranslate
 290                                 , domEmail =       choose  domEmail
 291                                 , domLoc =         choose  domLoc
 292                                 , domInfo =        mergelm domInfo
 293                                 , domNs =          mergelm domNs
 294                                 , domDelegate =    mergelm domDelegate
 295                                 , domImport =      mergelm domImport
 296                                 , domSubmap =      mergelm domSubmap
 297                                 , domFingerprint = mergelm domFingerprint
 298                                 , domDs =          mergelm domDs
 299                                 , domMx =          mergelm domMx
 300                                 , domSrv =         mergelm domSrv
 301                                 , domTlsa =        mergelm domTlsa
 302                                 }
 303           where
 304                 mergelm x = merge (x sub) (x dom)
 305 -- Because it is not possible to define instance of merge for Strings,
 306 -- we have to treat string elements separately, otherwise strings are
 307 -- 'unioned' along with the rest of lists. Ugly, but alternatives are worse.
 308                 choose field = case field dom of
 309                         Nothing -> field sub
 310                         Just x  -> Just x