configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([pam_pcsc_cr], 0.9.2)
   4 AC_CONFIG_SRCDIR([pam_pcsc_cr.c])
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AM_INIT_AUTOMAKE
   7 AM_CONFIG_HEADER([config.h])
   8 AC_LANG_C
   9 AC_PROG_CC
  10
  11 if test "X$CC" = "Xgcc"; then
  12   CFLAGS="$CFLAGS -Wall"
  13 fi
  14
  15 AC_PROG_MAKE_SET
  16 AC_SUBST(PROGS)dnl
  17 AC_SUBST(LIBPROGS)dnl
  18 AC_PROG_INSTALL
  19 AM_PROG_LIBTOOL
  20 PKG_PROG_PKG_CONFIG
  21
  22 AC_CHECK_HEADERS([security/pam_appl.h], [], [
  23   AC_MSG_ERROR([[PAM headers not found]])
  24 ])
  25 AC_CHECK_HEADERS([security/pam_modules.h security/pam_ext.h], [], [], [
  26 #include <sys/types.h>
  27 #include <security/pam_appl.h>
  28 ])
  29 AC_CHECK_LIB([pam], [pam_start])
  30 AC_CHECK_FUNCS([pam_get_authtok])
  31 AC_ARG_WITH(pam-dir,
  32         [  --with-pam-dir=DIR      path to install the PAM module (/lib/security)],
  33         [PAMDIR="$withval"],
  34         [
  35 case $prefix in
  36 */_inst) PAMDIR='${exec_prefix}/lib/security' ;;
  37 *)       PAMDIR=/lib/security ;;
  38 esac
  39 ])
  40 AC_SUBST(PAMDIR)
  41 AC_MSG_NOTICE([Installation target PAMDIR=${PAMDIR}])
  42
  43 PKG_CHECK_MODULES([PCSC], [libpcsclite])
  44 CPPFLAGS="$PCSC_CFLAGS $CPPFLAGS"
  45 LIBS="$PCSC_LIBS $LIBS"
  46
  47 PKG_CHECK_MODULES([OPENSSL], [libcrypto], [], [:])
  48 AS_IF([test "x$OPENSSL_CFLAGS" != "x" -o "x$OPENSSL_LIBS" != "x" ], [
  49   use_openssl=yes
  50 ])
  51 CPPFLAGS="$OPENSSL_CFLAGS $CPPFLAGS"
  52 LIBS="$OPENSSL_LIBS $LIBS"
  53
  54 AC_ARG_ENABLE(tomcrypt,
  55         [  --enable-tomcrypt       use libtomcrypt even when openssl is present])
  56
  57 AS_IF([test "x$use_openssl" != "xyes" -o "x$enable_tomcrypt" = "xyes"], [
  58   PKG_CHECK_MODULES([TOMCRYPT], [libtomcrypt], [], [:])
  59 ])
  60 AS_IF([test "x$TOMCRYPT_CFLAGS" != "x" -o "x$TOMCRYPT_LIBS" != "x" ], [
  61   use_tomcrypt=yes
  62 ])
  63 CPPFLAGS="$TOMCRYPT_CFLAGS $CPPFLAGS"
  64 LIBS="$TOMCRYPT_LIBS $LIBS"
  65
  66 AC_ARG_ENABLE(gcrypt,
  67         [  --enable-gcrypt         use libgcrypt even when openssl or libtomcrypt
  68                           is present])
  69
  70 AS_IF([test "x$use_openssl" != "xyes" && test "x$use_tomcrypt" != "xyes" || \
  71         test "x$enable_tomcrypt" = "xyes"], [
  72   AM_PATH_LIBGCRYPT()
  73 ])
  74 AS_IF([test "x$LIBGCRYPT_CFLAGS" != "x" -o "x$LIBGCRYPT_LIBS" != "x" ], [
  75   use_gcrypt=yes
  76 ])
  77 CPPFLAGS="$LIBGCRYPT_CFLAGS $CPPFLAGS"
  78 LIBS="$LIBGCRYPT_LIBS $LIBS"
  79
  80 AS_IF([test "x$use_openssl" != "xyes" -a "x$use_tomcrypt" != "xyes" -a "x$use_gcrypt" != "xyes"], [
  81   AC_MSG_ERROR([[Neither openssl, tomcrypt or gcrypt libraries present]])
  82 ])
  83
  84 AS_IF([test "x$use_openssl" = "xyes"], [
  85   CRYPTO_OBJS+=" ossl_crypto.lo"
  86   AC_DEFINE([HAVE_OPENSSL], [1], [Use openssl libcrypto])
  87 ])
  88 AS_IF([test "x$use_tomcrypt" = "xyes"], [
  89   CRYPTO_OBJS+=" tom_crypto.lo"
  90   AC_DEFINE([HAVE_TOMCRYPT], [1], [Use libtomcrypt])
  91 ])
  92 AS_IF([test "x$use_gcrypt" = "xyes"], [
  93   CRYPTO_OBJS+=" gnu_crypto.lo"
  94   AC_DEFINE([HAVE_GCRYPT], [1], [Use libgcrypt])
  95 ])
  96 AC_SUBST(CRYPTO_OBJS)
  97
  98 dnl Checks for header files.
  99 AC_HEADER_STDC
 100 AC_HEADER_TIME
 101
 102 AC_CHECK_HEADERS([winscard.h reader.h], [],
 103   [AC_MSG_ERROR([[pcsclite headers not found]])])
 104 AC_CHECK_LIB([pcsclite], [SCardEstablishContext], [],
 105   [AC_MSG_ERROR([[pcsclite library not useable]])])
 106
 107 AC_CONFIG_FILES([Makefile])
 108 AC_OUTPUT